Flex Drop元素太大时

Question

在Flex Mobile中，我在操作栏中有几个按钮。在屏幕非常小的设备上（例如HTC Wildfire），不能显示所有按钮。有没有办法让Flex在不适合时隐藏元素？我知道这是可能通过使用状态和测试屏幕的宽度，但我希望有另一种方式..

Answer 1

这里有一个非常简单的Spark布局类是水平排列的对象，下探赢得”任何项目不适合。

package 
{ 
    import mx.core.ILayoutElement; 

    import spark.layouts.supportClasses.LayoutBase; 

    public class DroppableHorizontalLayout extends LayoutBase 
    { 
     private static const PADDING:Number = 5; 

     public function DroppableHorizontalLayout() 
     { 
      super(); 
     } 

     override public function updateDisplayList(width:Number, height:Number):void 
     { 
//   super.updateDisplayList(width,height); // super method doesn't do anything 
      var currentXCoordinate:Number = 0; 
      var numKids:int = target.numChildren; 
      for (var i:int=0; i < numKids; i++) 
      { 
       var currentItem:ILayoutElement = target.getElementAt(i); 
       var itemWidth:Number = currentItem.getPreferredBoundsWidth(); 
       if (currentXCoordinate + itemWidth < width) 
       { 
        currentItem.setLayoutBoundsSize(itemWidth, currentItem.getPreferredBoundsHeight()); 
        currentItem.setLayoutBoundsPosition(currentXCoordinate, 0); // or whatever the Y coordinate should be 
        currentXCoordinate = currentXCoordinate + itemWidth + PADDING; 
       } 
       else 
       { 
        break; // no reason to keep iterating, nothing else will fit... 
       } 
      } 
     } 
    } 
} 

编写具有典型Flex布局类的所有功能的布局不是微不足道的。但是你当然可以做一些简单的事情，像上面这样，遍历子对象，设置它们的大小/位置，在这种情况下，不会打扰不适合渲染的东西。

Answer 2

您可以检查ApplicationDPI值;并隐藏更高分辨率的显式内容。大多数片剂提供160dpi;而大多数手机提供240dpi。 iPhone 4提供320dpi的屏幕。我不确定iPad Retina显示屏幕。