PowerDesigner 使用笔记二(批量将Name列内容同步到comment中)
'******************************************************************************
'* File: name2comment.vbs
'* Title: Name to Comment Conversion
'* Model: Physical Data Model
'* Objects: Table, Column, View
'* Author: steveguoshao
'* Created: 2013-11-29
'* Mod By:
'* Modified:
'* Version: 1.0
'* Memo: Modify from name2code.vbs
'******************************************************************************
Option Explicit
ValidationMode = True
InteractiveMode = im_Batch
Dim mdl ' the current model
' get the current active model
Set mdl = ActiveModel
If (mdl Is Nothing) Then
MsgBox "There is no current Model "
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
MsgBox "The current model is not an Physical Data model. "
Else
ProcessFolder mdl
End If
' This routine copy name into comment for each table, each column and each view
' of the current folder
Private sub ProcessFolder(folder)
Dim Tab 'running table
for each Tab in folder.tables
if not tab.isShortcut then
tab.comment = tab.name
Dim col ' running column
for each col in tab.columns
col.comment= col.name
next
end if
next
Dim view 'running view
for each view in folder.Views
if not view.isShortcut then
view.comment = view.name
end if
next
' go into the sub-packages
Dim f ' running folder
For Each f In folder.Packages
if not f.IsShortcut then
ProcessFolder f
end if
Next
end sub
在PowerDesigner 使用中设计表结构的时候如果需要将Name列的内容批量同步到对应的字段的comment(注释)列中,则可以用如下设置。
1,打开设计好的E-R 图工程 依次点击工具栏中的【Tools】--->【Excute Commends】---->【Edit/Run Script】 如下图所示:
2,弹出Run/Edit Script 对话框,如下图所示:
3,复制本文开始段代码,保存为name2comment.vbs文件,点击上图工具栏中的第三个“打开文件”按钮,选择刚保存好的脚本文件,如下图所示,点击【Run】按钮,执行脚本
4,关闭窗口,再打开任意一个表设计,会惊喜的发现,列的comment中的内容和Name列的内容一样 了。