如何一次读取多个值作为PLSQL中单个变量的输入?
问题描述:
你能帮我传递输入值(在执行时:我的意思是一次输入单个变量的多个值)。如何一次读取多个值作为PLSQL中单个变量的输入?
这里是我的代码,我一次只给一个输入一个硬编码输入或一个输入。
declare
type TEmpRec is record (
EmployeeID EMPLOYEES.EMPLOYEE_ID%TYPE,
LastName EMPLOYEES.LAST_NAME%TYPE
);
type TEmpList is table of TEmpRec;
vEmpList TEmpList;
---------
function EmpRec(pEmployeeID EMPLOYEES.EMPLOYEE_ID%TYPE,
pLastName EMPLOYEES.LAST_NAME%TYPE default null) return TEmpRec is
-- Effective "Record constructor"
vResult TEmpRec;
begin
vResult.EmployeeID := pEmployeeID;
vResult.LastName := pLastName;
return vResult;
end;
---------
procedure SearchRecs(pEmpList in out nocopy TEmpList) is -- Nocopy is a hint to pass by reference (pointer, so small) rather than value (actual contents, so big)
vIndex PLS_integer;
begin
if pEmpList is not null then
vIndex := pEmpList.First;
while vIndex is not null -- The "while" approach can be used on sparse collections (where items have been deleted)
loop
begin
select LAST_NAME
into pEmpList(vIndex).LastName
from EMPLOYEES
where EMPLOYEE_ID = pEmpList(vIndex).EmployeeID;
exception
when NO_DATA_FOUND then
pEmpList(vIndex).LastName := 'F'||pEmpList(vIndex).EmployeeID;
end;
vIndex := pEmpList.Next(vIndex);
end loop;
end if;
end;
---------
procedure OutputRecs(pEmpList TEmpList) is
vIndex PLS_integer;
begin
if pEmpList is not null then
vIndex := pEmpList.First;
while vIndex is not null
loop
DBMS_OUTPUT.PUT_LINE ('pEmpList(' || vIndex ||') = '|| pEmpList(vIndex).EmployeeID||', '|| pEmpList(vIndex).LastName);
vIndex := pEmpList.Next(vIndex);
end loop;
end if;
end;
begin
vEmpList := TEmpList(EmpRec(100),
EmpRec(34),
EmpRec(104),
EmpRec(110));
SearchRecs(vEmpList);
OutputRecs(vEmpList);
end;
/
上面的程序在时间上取值为1。 但是,我试着如下,但无法成功。
我试图从控制台一次输入输入(100,34,104,100),而不是对输入(或)在输入时进行硬编码。
片段在DECLARE部分:
declare
type TEmpRec is record (
EmployeeID EMPLOYEES.EMPLOYEE_ID%TYPE,
LastName EMPLOYEES.LAST_NAME%TYPE
);
type TEmpList is table of TEmpRec;
v_input TEmpList := TEmpList(&v_input); -- to read multiple input at once
vEmpList TEmpList;
在最后BEGIN部分:
BEGIN
FOR j IN v_input.FIRST .. v_input.LAST LOOP
vEmpList := TEmpList(EmpRec(v_input(j).EmployeeID)); --to assign input values to vEmptList
SearchRecs(vEmpList);
OutputRecs(vEmpList);
end loop;
end;
/
错误DECLARE部分: PLS-00306:错误数量或类型的参与调用'TEMPLIST' 最后一个错误ction: PLS-00320:这个表达式的类型的声明不完整或畸形
作为一个例子:在时间,我能够读取相同的变量多个输入值,但我无法通过这是一个输入,但无法弄清楚如何使这个作为输入我的主程序。
DECLARE
TYPE t IS TABLE OF VARCHAR2(100);
ORDERS t := t(&ORDERS);
BEGIN
FOR j IN ORDERS.FIRST .. ORDERS.LAST LOOP
dbms_output.put_line(ORDERS(j));
END LOOP;
END;
/
输出: PL/SQL过程已成功完成。 订单输入值:321153678
谢谢。
答
由于您有一个record
变量的集合,您需要分别通过employee_ids
和员工last_names
。你打算如何通过一个镜头通过他们? 下面是一个示例脚本,它用3个收集元素的2个输入实现了您想要的内容。
首先,创建一个集合TYPE
和一个PIPELINED function
将逗号分隔值转换为Collections
- f_convert2
。
CREATE TYPE test_type AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE FUNCTION f_convert2(p_list IN VARCHAR2)
RETURN test_type
PIPELINED
AS
l_string LONG := p_list || ',';
l_comma_index PLS_INTEGER;
l_index PLS_INTEGER := 1;
BEGIN
LOOP
l_comma_index := INSTR(l_string, ',', l_index);
EXIT WHEN l_comma_index = 0;
PIPE ROW (SUBSTR(l_string, l_index, l_comma_index - l_index));
l_index := l_comma_index + 1;
END LOOP;
RETURN;
END f_convert2;
/
然后在您的匿名块中分别为employee_ids和last_name传递值。
SET SERVEROUTPUT ON
DECLARE
TYPE temprec IS RECORD (employeeid employees.employee_id%TYPE,
lastname employees.last_name%TYPE);
TYPE templist IS
TABLE OF temprec;
vemplist templist;
v_no_of_rec NUMBER := 10;
v_empl_ids VARCHAR2(100) := '&empl_ids';
v_empl_lnames VARCHAR2(100) := '&empl_lnames';
BEGIN
SELECT employee_id,last_name
BULK COLLECT
INTO
vemplist
FROM
(
SELECT
ROWNUM rn,
column_value employee_id
FROM
TABLE (f_convert2(v_empl_ids))
) a
JOIN (
SELECT
ROWNUM rn,
column_value last_name
FROM
TABLE (f_convert2(v_empl_lnames))
) b ON a.rn = b.rn;
FOR i in 1..vemplist.COUNT LOOP
DBMS_OUTPUT.PUT_LINE(vemplist(i).employeeid || ' ' ||vemplist(i).lastname);
END LOOP;
END;
/
而不是简单的JOIN以上,如果你使用OUTER JOIN
(FULL
或LEFT
),你可以处理,而无需编写逻辑来检查每个值遗漏值。
'TEmpRec'是一个普通的PL/SQL记录类型,所以它没有构造函数。如果你想要一个构造函数,你需要创建一个对象类型。如果您想要更详细的答案,[mcve](https://*.com/help/mcve)会使问题更清楚。 –