如何从Perl中的二进制文件中读取无符号整型值？

Question

比方说，我有一个被格式化像

[unsigned int(length of text)][text][unsigned int(length of text)][text][unsigned int(length of text)][text] 

一个二进制文件和文件只是不断重复这一模式。如何读取unsigned int并在Perl中打印出文本块？

此外，这是一个二进制文件，而不是纯文本文件。

Answer 1

这是一个小的工作示例。

#!/usr/bin/perl 

use strict; 
use warnings; 

my $INT_SIZE = 2; 
my $filename = 'somefile.bin'; 

open my $fh, '<', $filename or die "Couldn't open file $filename: $!\n"; 

binmode $fh; 

while (read $fh, my $packed_length, $INT_SIZE) { 

    my $text = ''; 
    my $length = unpack 'v', $packed_length; 

    read $fh, $text, $length; 

    print $length, "\t", $text, "\n"; 
} 

变化INT_SIZE和解包模板的尺寸和字节顺序，以适应（无论是“V”或“N”或“V”或“N”）。有关更多详细信息，请参见unpack联机帮助页。

Answer 2

您需要在数据上使用unpack函数。退房Pack/Unpack Tutorial (aka How the System Stores Data)。

这应该让你在正确的方向前进（假设32位）：

#!/usr/bin/perl 

use strict; 

my $strBuf = "perl rocks"; 
my $packed = pack("I Z15", length($strBuf), $strBuf); 
{ 
    open(my $binFile, '>', "test.bin") || die("Error opening file\n"); 
    binmode $binFile; 
    print $binFile $packed; 
    close $binFile; 
} 


open(my $binFile, '<', "test.bin") || die("Error opening file\n"); 
binmode $binFile; 

my $buffer; 
read($binFile, $buffer, 4); ## Read out unsigned int binary data 
my $length = unpack("I", $buffer); ## Unpack the data 

read($binFile, $buffer, $length); ## Read the length out as binary 
my $string = unpack("Z$length", $buffer); ## Unpack the string data in buffer 

print "Len: $length String: $string\n"; 
exit; 

Answer 3

除了使用unpack，作为RC所指出的，你几乎肯定会想用read或sysread读取数据从文件中。

Answer 4

这里没有足够的信息来完全解决这个问题。

需要的是长度字段和文本字段的确切格式。是2个字节，4个字节还是8个字节？ （都可能。）也是小端或大端？

给出此信息，然后使用读取函数访问第一个整数，并使用位操作或解压缩函数将其转换为数字。

下一个问题是文本字符串的确切格式。它是ASCII，EBCDIC还是UTF格式？知道这一点，您可以计算字符串的长度，并使用一个或多个读取操作来获取原始字符串，您可能必须将其转换为更易于管理的形式。

另一件事 - 你需要以二进制模式打开文件，否则你可能无法获得预期的结果。