转换UTF8字符串转换成数值在Perl
答
unpack
将比split
和ord
更高效,因为它不必让一帮暂时1字符串:
use utf8;
my $str = '中國c'; # Chinese language of china
my @codepoints = unpack 'U*', $str;
print join(',', @codepoints) . "\n"; # prints 20013,22283,99
快速基准测试显示它比split+ord
快3倍左右:
use utf8;
use Benchmark 'cmpthese';
my $str = '中國中國中國中國中國中國中國中國中國中國中國中國中國中國c';
cmpthese(0, {
'unpack' => sub { my @codepoints = unpack 'U*', $str; },
'split-map' => sub { my @codepoints = map { ord } split //, $str },
'split-for' => sub { my @cp; for my $c (split(//, $str)) { push @cp, ord($c) } },
'split-for2' => sub { my $cp; for my $c (split(//, $str)) { $cp = ord($c) } },
});
结果:
Rate split-map split-for split-for2 unpack
split-map 85423/s -- -7% -32% -67%
split-for 91950/s 8% -- -27% -64%
split-for2 125550/s 47% 37% -- -51%
unpack 256941/s 201% 179% 105% --
的差异不太明显与较短的字符串,但unpack
仍然是两倍以上的速度。 (split-for2
比其他分裂速度更快一点,因为它不建立码点的列表。)
答
foreach my $c (split(//, $str))
{
print ord($c), "\n";
}
或压制成单行:my @chars = map { ord } split //, $str;
Data::Dumper版,这将产生:
$VAR1 = [
20013,
22283,
99
];
答
要让UTF8在源代码中承认的,你必须use utf8;
事先:
$ perl
use utf8;
my $str = '中國c'; # Chinese language of china
foreach my $c (split(//, $str))
{
print ord($c), "\n";
}
__END__
20013
22283
99
以上简洁,
print join ',', map ord, split //, $str;
答
http://www.perl.com/pub/2012/04/perlunicook-standard-preamble.html
#!/usr/bin/env perl
use utf8; # so literals and identifiers can be in UTF-8
use v5.12; # or later to get "unicode_strings" feature
use strict; # quote strings, declare variables
use warnings; # on by default
use warnings qw(FATAL utf8); # fatalize encoding glitches
use open qw(:std :utf8); # undeclared streams in UTF-8
# use charnames qw(:full :short); # unneeded in v5.16
# http://perldoc.perl.org/functions/sprintf.html
# vector flag
# This flag tells Perl to interpret the supplied string as a vector of integers, one for each character in the string.
my $str = '中國c';
printf "%*vd\n", ",", $str;
“中国的中国语言”?为什么'中国'? – Zaid 2010-08-22 20:19:40
我想它应该读*中文单词“中国”*。 – daxim 2010-08-23 09:39:42