如何将Flash与Php整合
问题描述:
我想将我的flash文件与php代码整合。我从如何将Flash与Php整合
http://www.kirupa.com/developer/actionscript/flashphpxml_integration2.htm
function lv(l, n, t, e, f) {
if (l == undefined) {
l = new LoadVars();
l.onLoad = function() {
var i;
n.htmlText = "";
if (t == undefined) {
n.htmlText += "<b>" + this["title" + e] + "</b><br>";
} else {
for (i = 0; i < this.n; i++) {
n.htmlText += "<a href='" + this["link" + i] + "'>" + this["title" + i] + "</a><br>";
}
}
};
}
l.load(f);
}
lv(sites_txt, "cycle", null, "sites.php");
我没有在论坛,但同时考虑到所有步骤运行代码我得到错误,如
1180: Call to a possibly undefined method LoadVars.
Warning: 1060: Migration issue: The method LoadVars is no longer supported. For more information, see the URLVariables class, the URLRequest.urlVariables and URLRequest.postData properties, and the URLLoader.dataFormat property..
1136: Incorrect number of arguments. Expected 5.
我是新下面的代码到flash脚本请引导我如何排除这些问题
答
您的示例代码是AS2,这里是你如何从和PHP使用AS3使用发送和接收数据:
- 的URLRequest
- 的URLLoader
- 的URLVariables
这里有一个快速的I类有为你制作:
package
{
import flash.net.URLRequest;
import flash.net.URLLoader;
import flash.net.URLVariables;
import flash.net.URLRequestMethod;
import flash.events.Event;
public class PHPData extends Object
{
/**
* Sends data to a PHP script
* @param script A URL to the PHP script
*/
public function send(script:String, vars:URLVariables):void
{
var req:URLRequest = new URLRequest(script);
req.data = vars;
req.method = URLRequestMethod.POST;
var loader:URLLoader = new URLLoader();
loader.load(req);
// listeners
loader.addEventListener(Event.COMPLETE, _complete);
}
/**
* Called when a response has been received from a PHP script
* @param e Event.COMPLETE
*/
private function _complete(e:Event):void
{
var vars:URLVariables = new URLVariables(e.target.data);
var i:String;
for(i in vars)
{
trace(i + ": " + vars[i]);
}
e.target.removeEventListener(Event.COMPLETE, _complete);
}
}
}
有了这个,你可以发送数据到给定的PHP脚本,格式为URLVariables
。
URLVariables
易于制备,像这样:
var vars:URLVariables = new URLVariables();
vars.myvar = "some value";
vars.myothervar = 30;
下面是一个简单的例子,我已经嘲笑了你,它发送一个字符串到PHP,然后PHP发回散列为MD5的字符串,也有一个时间戳附作为次要价值。
var php:PHPData = new PHPData();
var vars:URLVariables = new URLVariables();
vars.myvar = "marty";
php.send("http://projectavian.com/md5.php", vars);
你这个输出将是类似的东西来:
response: bb3761a33402b4f82806178e79ec5261
time: 1306133172
只是改变了PHPData
类的_complete
方法来处理响应所需数据:)
我因为你的问题有mysql标签,所以将其扔进去。
所有你需要做的是标准的插入,然后选择在PHP脚本查询和你的结果编码成这种格式:
var=1&other=2&more=three
所以你可以有..
<?php
mysql_connect(/* ?? */);
mysql_select_db(/* ?? */);
// INSERT example
$thing = mysql_real_escape_string($_POST["thing"]);
mysql_query("INSERT INTO table VALUES('','$thing')");
// SELECT for response
$id = mysql_real_escape_string($_POST["uid"]);
$query = mysql_query("SELECT * FROM table WHERE id='$uid' LIMIT 1");
// send response
$r = mysql_fetch_assoc($query);
echo 'fname=' . $r["first_name"] . '&lname=' . $r["last_name"];
?>
Load忱是一个AS2班 - 我会告诉你一个AS3的例子。 – Marty 2011-05-23 06:35:53