SAS - 使用另一列中的值动态创建列名称

问题描述：

我有一列包含许多从XML解析器分析的标志。数据如下所示：SAS - 使用另一列中的值动态创建列名称

USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N;

我必须创建一个包含所有这些列名称的表来捕获标志。如：

USERKEYED VALMATCH DEVICEVERIFIED EXCEPTION USERREGISTRD ASSOCIATE EXTERNAL GROSSGIVEN UMAPPED 
Y N N N N Y N Y N 
Y N N N N Y Y Y N 
Y N N Y N Y N Y N

如何在SAS中动态捕获值？无论是在数据步骤还是PROC步骤？

在此先感谢。

在数据中读入第一个变量作为变量，第二个变量作为值读取。然后转置数据。 – Reeza

数据集中或文本文件中的字符变量中的字符串是否需要读取？如果它是在一个文本文件中，那么也许你可以使用命名输入样式来阅读。但是你需要知道变量名才能写入输入语句。 – Tom

谢谢你的回复。现在我尝试了字符串函数，它工作正常。尽管它正在工作，但是对于我来说代码看起来并不令人满意，如果将更多标志添加到列中，它需要更改代码。 –

答

让我们从您的示例输出数据开始。

data expect ; 
    id+1; 
    length USERKEYED VALMATCH DEVICEVERIFIED EXCEPTION 
     USERREGISTRD ASSOCIATE EXTERNAL GROSSGIVEN UMAPPED $1 ; 
    input USERKEYED -- UMAPPED; 
cards4; 
Y N N N N Y N Y N 
Y N N N N Y Y Y N 
Y N N Y N Y N Y N 
;;;;

现在我们可以重新创建你的榜样输入数据：

data have ; 
    do until (last.id); 
    set expect ; 
    by id ; 
    array flag _character_; 
    length string $200 ; 
    do _n_=1 to dim(flag); 
     string=catx(';',string,catx('=',vname(flag(_n_)),flag(_n_))); 
    end; 
    end; 
    keep id string; 
run;

这将是这样的：

USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N 
USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=Y;GROSSGIVEN=Y;UMAPPED=N 
USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=Y;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N

所以处理这一点，我们需要从变量解析出对STRING转化为多个观察值，其中个体对的值分为NAME和VALUE变量。

data middle ; 
    set have ; 
    do _n_=1 by 1 while(_n_=1 or scan(string,_n_,';')^=' '); 
    length name $32 ; 
    name = scan(scan(string,_n_,';'),1,'='); 
    value = scan(scan(string,_n_,';'),2,'='); 
    output; 
    end; 
    keep id name value ; 
run;

然后我们可以使用PROC TRANSPOSE将这些观察值转换成变量。

proc transpose data=middle out=want (drop=_name_) ; 
    by id; 
    id name ; 
    var value ; 
run;

答

DATA <MY_DATASET>; 
SET INPUT_DATASET; 
USERKEYED = substr(input_column, find(input_column, 'USERKEYED=')+10,1); 
VALMATCH = substr(input_column, find(input_column, 'VALMATCH=')+9,1); 
DEVICEVERIFIED = substr(input_column, find(input_column, 'DEVICEVERIFIED=')+15,1); 
EXCEPTION = substr(input_column, find(input_column, 'EXCEPTION=')+10,1); 
USERREGISTRD = substr(input_column, find(input_column, 'USERREGISTRD=')+13,1); 
ASSOCIATE = substr(input_column, find(input_column, 'ASSOCIATE=')+10,1); EXTERNAL = substr(input_column, find(input_column, 'EXTERNAL=')+9,1); 
GROSSGIVEN = substr(input_column, find(input_column, 'GROSSGIVEN=')+11,1); 
UMAPPED = substr(input_column, find(input_column, UMAPPED=')+8,1); 
run;

答

您拥有的数据是一系列名称/值对，使用;作为分隔符。我们可以在一个时间提取每个名称/值对中的一个，然后解析那些入值：

data tmp; 
    length my_string next_pair name value $200; 
    my_string = "USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N;"; 
    cnt = 1; 
    next_pair = scan(my_string,cnt,";"); 
    do while (next_pair ne ""); 
    name = scan(next_pair,1,"="); 
    value = scan(next_pair,2,"="); 
    output; 
    cnt = cnt + 1; 
    next_pair = scan(my_string,cnt,";"); 
    end; 
    keep name value; 
run;

得到：

name    value 
=================== ===== 
USERKEYED   Y 
VALMATCH   N 
DEVICEVERIFIED  N 
EXCEPTION   N 
USERREGISTRD  N 
ASSOCIATE   Y 
EXTERNAL   N 
GROSSGIVEN   Y 
UMAPPED    N

然后，我们可以调换，以便该名称用于该数据列名：

proc transpose data=tmp out=want(drop=_name_); 
    id name; 
    var value; 
run;

它给你所需的表。

这适用于单记录场景。如果我没有错，如果有多个记录需要从数据步骤传递给my_string，则Transpose将不起作用。 ??? –

您需要一个或多个变量来唯一标识可以在BY语句中传递给PROC TRANSPOSE的原始行。 – Tom

@NagaVemprala如果你更新你的数据，我会更新我的代码=） –

答

我的答案本质上是第一块代码，其余的只是解释，一个替代方案和一个不错的提示。

根据您所提供的答案，输入数据已经是一个SAS数据集，因此可以读取创建的SAS代码的文件，然后可以使用%include运行等proc transpose是不要求：

filename tempcode '<path><file-name.txt>'; /* set this up yourself */ 

/* write out SAS code to the fileref tempcode */ 
data _null_; 
    file tempcode; 
    set have; 
    if _n_=1 then 
    put 'Y="Y"; N="N"; drop Y N;'; 
    put input_column; 
    put 'output;'; 
run; 

/* %include the code to create the desired output */ 
data want; 
    %include tempcode; 
run;

由于输入数据已经几乎看起来像SAS赋值语句，我们采取的这种优势，因此已经从fileref tempcode使用%include运行SAS代码应该是这样的：

Y="Y"; N="N"; drop Y N; 
USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N; 
output; 
USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=N;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=Y;GROSSGIVEN=Y;UMAPPED=N; 
output; 
USERKEYED=Y;VALMATCH=N;DEVICEVERIFIED=N;EXCEPTION=Y;USERREGISTRD=N;ASSOCIATE=Y;EXTERNAL=N;GROSSGIVEN=Y;UMAPPED=N; 
output;

作为替代方案，fileref tempcode可以包含所有用于数据的步骤“data want;”的代码：

/* write out entire SAS data step code to the fileref tempcode */ 
data _null_; 
    file tempcode; 
    set have end=lastrec; 
    if _n_=1 then 
    put 'data want;' 
     /'Y="Y"; N="N"; drop Y N;'; 

    put input_column; 
    put 'output;'; 

    if lastrec then 
    put 'run;'; 
run; 

%include tempcode; /* no need for surrounding SAS code */

作为尖端，看到在日志可以使用下面的变化由%include正在处理的代码：

%include tempcode/source2;

希望这一切都有助于（和工作！）

问候，阿米尔。

SAS - 使用另一列中的值动态创建列名称

相关推荐