如何关闭Delphi中的非模态窗体

Question

这里已经讨论过了，但不是详细说明。

我在尝试让非模态子窗体关闭时遇到了麻烦。我让它通知父母，但我得到抽象的错误和其他例外。我究竟做错了什么？父母是否必须释放非模态形式，或者不要再尝试通过该变量来访问它？

主要形式有：

NonModal := NonModalTForm.Create(Self); 
NonModal.Callback := Callback; 
NonModal.Show; 

Procedure TForm.Callback; // called by non-modal form when closing 
begin 
    FreeAndNil(NonModal); // or should this just be NonModal := nil so I don't try to access a dangling pointer? 
end; 

在NonModal.pas

procedure NonModalTForm.FormClose; 
begin 
    Callback; // calls parent 
end; 

Answer 1

使用隐藏，如果你想显示窗口以后。

如果要关闭它，请使用Close。 （关闭主窗口，关闭应用程序）。 关闭的确切操作取决于表单参数。

看近距离的来源：

procedure TCustomForm.Close; 
var 
    CloseAction: TCloseAction; 
begin 
    if fsModal in FFormState then 
    ModalResult := mrCancel 
    else 
    if CloseQuery then begin 
     if FormStyle = fsMDIChild then 
     if biMinimize in BorderIcons then 
      CloseAction := caMinimize 
     else 
      CloseAction := caNone 
     else 
     CloseAction := caHide; 
     DoClose(CloseAction); 
     if CloseAction <> caNone then 
     if Application.MainForm = Self then 
      Application.Terminate 
     else if CloseAction = caHide then 
      Hide 
     else if CloseAction = caMinimize then 
      WindowState := wsMinimized 
     else 
      Release; 
    end; 
end; 

但要小心免费。在左边的窗口队列中可能会有一些消息会导致崩溃。更好地使用Release来清理窗口。因为它在释放它之前等待消息。

Answer 2

你正在做你不应该做的事情。
在NonModalForm的onClose事件中，您调用一些直接释放它的代码，但它仍然在事件处理程序执行中，因此最终会产生一个无效的自身对象。
这就是为什么在表单上使用Release而不是Free的情况。

正如Gamecat指出的那样，只需简单地调用Close即可......
VCL的美妙之处在于它非常简单。

Answer 3

您可以致电close从FormClose事件以外的其他地方关闭窗体。在FormClose情况下，只需设置等于行动，以执行下列操作之一：

• caFree - 处置形式的完全
• caMinimize - 最小化形式
• caHide - 隐藏形式
• caNone - 忽略收盘

例如：

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction); 
begin 
    Action := caFree; 
end; 

Answer 4

当其他组件被释放时，VCL已经有了一个通知组件的机制。你可以这样使用它;

type 
    TfrmParent = class(TForm) 
    btnShowChild: TButton; 
    procedure btnShowChildClick(Sender: TObject); 
    private 
    FChild: TfrmChild; 
    public 
    procedure Notification(AComponent: TComponent; Operation: TOperation); override; 
    end; 


procedure TfrmParent.btnShowChildClick(Sender: TObject); 
begin 
    // Check status of child 
    if FChild = nil then 
    begin 
    // Child does not exist, create it 
    FChild:= TfrmChild.Create(Application); 
    FChild.Show; 

    // Ask Child to notify us when it is destroyed 
    FChild.FreeNotification(Self); 
    end 
    else 
    begin 
    // Child already exists 
    FChild.Show; 
    end; 
end; 

procedure TfrmParent.Notification(AComponent: TComponent; 
    Operation: TOperation); 
begin 
    inherited; 

    if (AComponent = FChild) and (Operation = opRemove) then 
    begin 
    // FChild is about to be freed, so set reference to Child to nil 
    FChild:= nil; 
    end; 
end; 

创建子窗体后，使用创建的窗体的FreeNotification方法来注册自己，当子窗体被破坏收到通知。

要对通知作出反应，请覆盖通知方法。在那里，你可以找出哪个组件被销毁，并将其与记住的子表单引用进行比较。当您收到通知时，只需将对子窗体的引用设置为零。

在孩子TfrmChild本身，你不必做任何事情，但什么skamradt写道：就在参数Actionb设置为caFree在OnClose事件。

Answer 5

不使用callback

只需拨打FreeAndNil(Self);以释放是为表单创建的所有内存资源。

记住这是你的实现代码创建的*对象。由Delphi设计的表单设计器创建的对象非常好。