批处理文件找到文件夹中的最新文件，然后复制并重命名为另一个文件夹

Question

在这里找到了同样的问题..我想使用代码，但我的数据。我绝不是程序员..然而，我可以采取几乎任何代码，并使其适用于我。

How to code a batch file to copy and rename the most recently dated file?

这里是我的

@echo on 
setLocal DisableDelayedExpansion 
pushd N:\ 
setLocal EnableDelayedExpansion 

for /f "tokens=* delims= " %%G in ('dir/b/od') do (set newest=%%G) 

copy %newest% G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv 

PAUSE 
POPD 

而结果...

C:\Documents and Settings\belcherj\Desktop\AMI_BATCH>setLocal DisableDelayedExpa 
nsion 

C:\Documents and Settings\belcherj\Desktop\AMI_BATCH>pushd N:\ 

N:\>setLocal EnableDelayedExpansion 

N:\>for /F "tokens=* delims= " %G in ('dir/b/od') do (set newest=%G) 

N:\>(set newest=System Blink Count__2012-06-27 01_00_46.csv) 

N:\>(set newest=System Blink Count__2012-06-28 01_00_32.csv) 

N:\>(set newest=System Blink Count__2012-06-29 01_00_33.csv) 

N:\>(set newest=System Blink Count__2012-06-30 01_00_42.csv) 

N:\>(set newest=System Blink Count__2012-07-01 01_00_32.csv) 

N:\>(set newest=System Blink Count__2012-07-02 01_00_31.csv) 

N:\>(set newest=System Blink Count__2012-07-03 01_00_29.csv) 

N:\>(set newest=System Blink Count__2012-07-04 01_00_39.csv) 

N:\>(set newest=System Blink Count__2012-07-05 01_00_34.csv) 

N:\>(set newest=System Blink Count__2012-07-06 01_00_31.csv) 

N:\>(set newest=System Blink Count__2012-07-07 01_00_32.csv) 

N:\>(set newest=System Blink Count__2012-07-08 01_00_30.csv) 

N:\>(set newest=System Blink Count__2012-07-09 01_00_40.csv) 

N:\>(set newest=System Blink Count__2012-07-10 01_00_29.csv) 

N:\>(set newest=System Blink Count__2012-07-11 01_00_44.csv) 

N:\>(set newest=System Blink Count__2012-07-12 01_00_34.csv) 

N:\>copy System Blink Count__2012-07-12 01_00_34.csv G:\Server_Files\AMI_DATA\TE 
XT_FILES\NewFile.csv 
The system cannot find the file specified. 

N:\>PAUSE 
Press any key to continue . . . 

我认为这是与在文件名中的空格..我尝试了一些我发现的代码，它给出了相同的结果。我接近只需要一点点推动。 感谢您的时间和帮助。

Answer 1

这应该工作

@echo off 
cd /d N:\ 
for /f "tokens=*" %%a in ('dir /b /od') do set newest=%%a 
echo f| xcopy "%newest%" G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv 

Answer 2

你是对的，你的直接问题是文件名中的空格。您可以通过添加引号来解决该问题：copy "%newest%" "G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv"

但还有其他问题。 FOR选项应该是“eol =：delims =”。如果文件名以空格或分号开头，则您现有的选项将会失败。

如果文件名包含感叹号，您的代码也可能会失败，因为您在使用FOR %% G变量时启用了延迟epansion。您启用延迟扩展，但您不使用它。

如果列出的最后一个“文件”碰巧是一个目录而不是文件，那么您的代码也会失败。您需要DIR /A-D选项来过滤目录名称。

糟糕！我的原始发布代码不起作用，因为PUSHD已被删除，DIR/B在输出中不包含路径信息。

下面是避免潜在问题的解决方案，并且还增加了一些额外的错误检查：

@echo on 
setlocal disableDelayedExpansion 
set "quit=pause & exit /b" 
pushd N:\ || %quit% 
set "newest=" 
for /f "eol=: delims=" %%F in ('dir /b /od /a-d') do set "newest=%%F" 
if defined newest copy "%newest%" G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv 
%quit% 

禁用延迟扩展可能是没有必要的，因为它是在大多数安装的默认状态。但它不能伤害。

由于使用SETLOCAL，一旦脚本结束，对环境的任何更改都将丢失。 （一旦脚本结束，就有一个隐含的ENDLOCAL）。 ENDLOCAL（隐式或显式）也解除了PUSHD的结果，这就是为什么POPD不是必需的。

我定义了一个退出“宏”，以便使用相同的两个命令始终退出脚本：PAUSE，然后是EXIT/B。脚本最后不需要EXIT/B，但它不会受伤。

通过按降序排列文件列出文件并使用GOTO在第一个文件后跳出循环，可以使脚本更加高效。

@echo on 
setlocal disableDelayedExpansion 
set "quit=pause & exit /b" 
pushd N:\ || %quit% 
set "newest=" 
for /f "eol=: delims=" %%F in ('dir /b /o-d /a-d') do set "newest=%%F" & goto :break 
:break 
if defined newest copy "%newest%" G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv 
%quit% 

或文件可以在循环中没有定义的环境变量被复制，此时该脚本可以立即结束：

@echo on 
setlocal disableDelayedExpansion 
set "quit=pause & exit /b" 
pushd N:\ || %quit% 
for /f "eol=: delims=" %%F in ('dir /b /o-d /a-d') do (
    copy "%%F" G:\Server_Files\AMI_DATA\TEXT_FILES\NewFile.csv 
    %quit% 
) 
%quit%