如何在Perl中对并行数组进行排序？

Question

我有几个相同长度的数组。我想排序第一个数组，并相应地使所有其他数组“排序”。例如，如果第一个数组是(7,2,9)，第二个数组是("seven","two","nine")，第三个数组是("VII","II","IX")（按照第一个数组值递增），我们将有(2,7,9)("two","seven","nine")和("II","VII","IX")。

我该怎么做？

Answer 1

重新组织数据，以一个单一的阵列，用于排序：

my @a = ([7, "seven", "VII"], [2, "two", "II"], ..); 
@a = sort { $a->[0] <=> $b->[0] } @a; 

然后重新创建原始阵列：

my(@a1, @a2, @a3); 

for (@a) { 
    push @a1, shift @$_; 
    push @a2, shift @$_; 
    push @a3, shift @$_; 
} 

Answer 2

如你发现，保持平行阵列可以是一个麻烦和错误俯卧。另一种方法是将相关信息保存在一起。

use strict; 
use warnings; 

# One array-of-hashes instead of three parallel arrays. 
my @numbers = (
    { arabic => 7, text => 'seven', roman => 'VII' }, 
    { arabic => 2, text => 'two', roman => 'II' }, 
    { arabic => 9, text => 'nine', roman => 'IX' }, 
); 

@numbers = sort { $a->{arabic} <=> $b->{arabic} } @numbers; 

Answer 3

虽然我同意尤金y和MvanGeest，通常最好的答案是切换到另一种数据结构，有时您可能想并行阵列（或至少，可能无法避免它们）实际上是一种并行排序并行数组的方法。它是这样的：

my @nums = (7, 2, 9); 
my @names = qw(seven two nine); 
my @roman = qw(VII II IX); 

my @sorted_indices = sort { $nums[$a] <=> $nums[$b] } 0..$#nums; 
@$_ = @{$_}[@sorted_indices] for \(@nums, @names, @roman); 

也就是说，产生指数对应于所有阵列的列表，然后根据，将放在“主”数组中的顺序进行排序它们。一旦我们有了索引的排序列表，重新排列所有数组以匹配。

最后一行可以写手写出来作为

@nums = @nums[@sorted_indices]; 
@names = @names[@sorted_indices]; 
@roman = @roman[@sorted_indices]; 

但我想，以减少所需的复制粘贴的量，甚至在某些微毛语法的成本。更多你知道...

Answer 4

我知道你已经接受了一个答案，并且还有其他很好的 答案在这里，但我会建议一些不同的：不要复制你的 数据。你只需要追踪一次阿拉伯数字 - >罗马映射 - 为什么 存储基本上重复的数字数组，并对每一个数组进行排序？ 只是排序主列表，并根据需要查找的引用数组中的其他值：

my @roman = qw(0 I II III IV V VI VII VIII IX X); 
my @text = qw(zero one two three four five six seven eight nine ten); 

my @values = (7, 2, 9); 
my @sorted_values = sort @values; 
my @sorted_roman = map { $roman[$_] } @sorted_values; 
my @sorted_text = map { $text[$_] } @sorted_values; 

use Data::Dumper; 
print Dumper(\@sorted_values, \@sorted_roman, \@sorted_text); 

打印：

$VAR1 = [ 
      2, 
      7, 
      9 
     ]; 
$VAR2 = [ 
      'II', 
      'VII', 
      'IX' 
     ]; 
$VAR3 = [ 
      'two', 
      'seven', 
      'nine' 
     ]; 

在实际环境中，我会建议使用库来执行 罗马并为您的文字转换：

use Roman; 
my @sorted_roman = map { roman($_) } @sorted_values; 

use Lingua::EN::Numbers 'num2en'; 
my @sorted_text = map { num2en($_) } @sorted_values;