提示输入哈斯克尔命令行应用程序

Question

下面的Haskell程序的密码提示用户在终端输入密码，并继续他是否已经进入了正确的：

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

不幸的是，密码将出现在当用户键入它时，我想要避免。

如何在不显示屏幕的情况下阅读用户键入的字符序列？为此目的，相当于getLine？

我在MacOS X上，但我希望它能在Windows和Linux上工作。

Answer 1

尝试了下：

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

使用the System.Posix.Terminal module可以在终端中禁用回声。但是，这需要POSIX支持，所以可能无法在Windows上工作（我没有检查）。

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

注意，标准输入是行缓冲，所以如果你使用putStr "Password:"而不是putStrLn，你需要先刷新缓冲区，否则提示会也有抑制作用。

Answer 3

有在System.Console.Haskeline一个getPassword。可能对你的情况有点矫枉过正，但有人会觉得它很有用。

一个例子：

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

正如我上面的评论，我建议你使用haskeline，这是一个完整的提示图书馆。我愉快地使用它LambdaCalculator没有投诉。

Answer 5

withEcho可以用少一点在降噪被写成：

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)