TIdTCPServer多播（Indy 9 + Delphi 7）

Question

我知道我在下面描述的不是技术上的多播，但我缺少更好的描述，我正在尝试做什么。

我目前有一个TIdTCPServer，它带有一个读取传入消息的OnExecute，将响应消息生成到一个线程安全队列中，然后调用一个函数来逐步遍历队列并将消息发送回客户端。这部分代码正在工作，并允许客户请求数据集。

当客户端更改服务器上的对象时，我希望所有客户端都知道此更改。该代码当前将通知消息添加到每个连接的每个队列中。我的问题是OnExecute不是循环的，所以直到服务器收到来自客户端的消息之后才调用在队列上发送消息的调用。

有没有办法让OnExecute循环？或者触发OnExecute进行连接的方法我知道我已排队等待消息？

我的过程TWinSocketSession对象具有对连接的引用并包含传出消息队列的代码。它还有一个名为SendMessages的过程，它遍历队列并调用Connection.Write。以下是我的OnExecute过程。

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread); 
    Var 
    i:   Integer; 
    strMessage: String; 
    begin 
    //find the Socket Session for connection 
    for i := 0 to m_usClientCount do 
     begin 
     if m_mWinSocketSession[i]<>Nil then 
      if (m_mWinSocketSession[i].Connection = Athread.Connection) then break; 
     end; 

    //read the message 
    strMessage := m_mWinSocketSession[i].Connection.ReadLn(#0,25,-1); 

    //parse the message and populate the Queue with outgoing messages 
    m_mWinSocketSession[i].ParseInString(strMessage); 

    //send all of the outgoing messages 
    m_mWinSocketSession[i].SendMessages; 
    end; 

Answer 1

是的，TIdTCPServer.OnExecute事件IS一个环形事件。当入站消息到达时触发不是。无论连接实际在做什么，它都会在连接的整个生命周期内以连续循环的方式触发。事件处理程序的职责是根据需要实现阻止行为。你的代码调用ReadLn()时指定了25ms的超时时间，所以它不会阻止事件处理程序及时退出，因此它可以立即重新进入。如果您的事件处理程序被阻止以及时退出，那么您的代码中的其他位置存在死锁问题。

我不过建议如下修改，：

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
var 
    i: Integer; 
begin 
    for i := 0 to m_usClientCount do 
    begin 
    if (m_mWinSocketSession[i] = nil) then 
    begin 
     m_mWinSocketSession[i] := TWinSocketSession.Create; 
     m_mWinSocketSession[i].Connection := AThread.Connection; 

     // for easier access in the other events... 
     AThread.Data := m_mWinSocketSession[i]; 

     Exit; 
    end; 
    end; 

    // cannot start a new session 
    AThread.Connection.Disconnect; 
end; 

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
var 
    session: TWinSocketSession; 
    i: Integer; 
begin 
    session := TWinSocketSession(AThread.Data); 
    AThread.Data := nil; 

    if session <> nil then 
    begin  
    for i := 0 to m_usClientCount do 
    begin 
     if m_mWinSocketSession[i] = session then 
     begin 
     m_mWinSocketSession[i] := nil; 
     Break; 
     end; 
    end; 
    session.Free; 
    end; 
end; 

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread); 
var 
    session: TWinSocketSession; 
    strMessage: String; 
begin 
    session := TWinSocketSession(AThread.Data); 

    //read a message 
    strMessage := AThread.Connection.ReadLn(#0, 25, -1); 
    if not AThread.Connection.ReadLnTimedOut then 
    begin 
    //parse the message and populate the Queue with outgoing messages 
    session.ParseInString(strMessage); 
    end; 

    //send all of the outgoing messages 
    session.SendMessages; 
end; 

这会工作更好，如果你能完全消除m_mWinSocketSession列表而直接分配新的队列在OnConnect事件的连接。当客户端断开连接时，OnDisconnect事件可以 释放队列。

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
begin 
    AThread.Data := TWinSocketSession.Create; 
    TWinSocketSession(AThread.Data).Connection := AThread.Connection; 
end; 

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
begin 
    session := TWinSocketSession(AThread.Data); 
    AThread.Data := nil; 
    session.Free; 
end;