如何获取有关计算机的信息？ [32位或64位]

Question

我如何获得有关Windows操作系统类型的信息？它是32位还是64位？我如何以编程方式获取这些信息？

Answer 1

您需要使用GetProcAddress()在运行时检查IsWow64Process()功能的可用性，就像这样：

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
    IsWow64: BOOL; 
begin 
    Result := False; 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
    pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
    Result := Assigned(pIsWow64Process) 
     and pIsWow64Process(GetCurrentProcess, IsWow64) and IsWow64; 
    FreeLibrary(DLLHandle); 
    end; 
end; 

，因为该功能仅适用于那些有一个64位的味道Windows版本。声明它为external将阻止您的应用程序在SP2以前的Windows 2000或Windows XP上运行。

编辑：

克里斯已经张贴了关于缓存出于性能的考虑结果的评论。对于这个特定的API函数，这可能不是必需的，因为kernel32.dll将一直存在（并且我无法想象一个程序甚至会在没有它的情况下加载），但对于其他函数，情况可能不同。因此，这里的是缓存功能结果的版本：

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
const 
    WasCalled: BOOL = False; 
    IsWow64: BOOL = False; 
begin 
    if not WasCalled then begin 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
     pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
     if Assigned(pIsWow64Process) then 
     pIsWow64Process(GetCurrentProcess, IsWow64); 
     WasCalled := True; 
     FreeLibrary(DLLHandle); 
    end; 
    end; 
    Result := IsWow64; 
end; 

缓存此功能结果安全的，因为API函数要么是有或没有，其结果不能在同一个Windows安装改变。甚至可以安全地从多个线程同时调用它，因为找到WasCalled为False10的两个线程都将调用该函数，将相同的结果写入相同的内存位置，并且之后仅将WasCalled设置为True。

Answer 2

如果a）你在windows和b）你可以访问注册表，那么HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Windows NT \ CurrentVersion应该是提供信息的。

Answer 3

我不知道如何在Delphi中调用Win32函数。

但是，如果您编写一个32位程序，您可以调用Win32 API IsWow64Process来了解您是否在64位操作系统中。

当然，如果你编写一个64位的exe文件，它只能运行在64位的Windows上，所以不需要问。

Answer 4

function IsWin64: Boolean; 
var 
    IsWow64Process : function(hProcess : THandle; var Wow64Process : BOOL): BOOL; stdcall; 
    Wow64Process : BOOL; 
begin 
    Result := False; 
    IsWow64Process := GetProcAddress(GetModuleHandle(Kernel32), 'IsWow64Process'); 
    if Assigned(IsWow64Process) then begin 
    if IsWow64Process(GetCurrentProcess, Wow64Process) then begin 
     Result := Wow64Process; 
    end; 
    end; 
end; 

Answer 5

除了IsWow64Process，将GetNativeSystemInfo API函数可能是你的兴趣（它在Windows单元定义），以了解更多有关你的CPU（或者你可以使用装配和CPUID）。

Answer 6

//没有测试但你可以试试这个

is64 := (Environment.GetEnvironmentVariable('ProgramW6432') <> ''); 

Answer 7

德尔福XE +

Uses System.SysUtils 

Function IsWin64Or32: string; 
Begin 
    if Pos('64-bit', TOSVersion.ToString) > 0 then 
    Result := '64-bit' 
    Else 
    Result := '32-bit'; 
End; 

例

lbl1.Caption := IsWin64Or32; 

Answer 8

function TForm2.Arch: string; 
begin 
if TOSVersion.Architecture=arIntelX86 then 
    Result := '32-bit' Else Result := '64-bit' 
end;