将MS-Access string> 255个字符传递到MS-Word字段

Question

我使用.FormFields("WordBookmarkName").Result = stringFromAccess方法将数据从MS-Access传递到MS-Word文档。

看来它只能传递255个字符。有什么方法可以在MS-Word中传递给我的领域？

编辑：

这是代码的简化版本，我使用的作品确定为255个字符：

Dim startForms As String 
Dim appWord As Word.Application 
Dim doc As Word.Document 

startForms = String(256, "x") 

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word. 

If Err.Number <> 0 Then 

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word. 

End If 

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True) 

With doc 

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field 
    .FormFields("wdStartForms").Result = startForms 

    .Visible = True 
    .Activate 

End With 

Set doc = Nothing 
Set appWord = Nothing 

JohnnyBones：这是我经过改编的代码你的答案;使用ActiveDocument是行不通的，所以我继续使用doc参考我就做，它似乎后，与256+字符来确定：

Dim startForms As String 
Dim appWord As Word.Application 
Dim doc As Word.Document 

startForms = String(256, "x") 

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word. 

If Err.Number <> 0 Then 

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word. 

End If 

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True) 

With doc 

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field 
    .Bookmarks("wdStartForms").Range.Fields(1).Result.Text = startForms 
    .Visible = True 
    .Activate 

End With 

Set doc = Nothing 
Set appWord = Nothing 

Answer 1

如果你使用：

Dim FmFld As FormField, Str1 As String 
Str1 = (a long string > 256 characters) 

Set FmFld = ActiveDocument.FormFields(1) 
FmFld.Result = Str1 

你会得到一个错误：“字符串太长”（一个荒谬的“设计”功能，因为你可以手动完成而没有问题！）。

相同的，如果你使用：

ActiveDocument.Formfields("Text1").Result = Str1 

你可以避开这个问题，通过使用：

ActiveDocument.Unprotect 
FmFld.Range.Fields(1).Result.Text = Str1 
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True 

或者如果你指的是按名称formfield：

ActiveDocument.Unprotect 
ActiveDocument.Bookmarks("Text1").Range.Fields(1).Result.Text = Str1 
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True 

您也可以尝试传递多个字符串并将它们连接起来，将每个字符串切分成少于255个字符的块。