VBA SPLIT函数详解
VBA编程是经常会用到字符串拆分函数SPLIT
,用法也不复杂,但是大家对于这个函数的参数未必完全了解,下面结合示例讲解一下参数的用法。
SPLIT
函数的语法格式如下:
Split(expression, [ delimiter, [ limit, [ compare ]]])
- express参数为需要拆分的字符串
- delimiter参数为拆分的分隔符,如果省略则使用空格做为分隔符
- limit参数指定返回字符串的数量
- compare参数指定拆分子字符串时的比较类型
先来看一个示例,现在需要拆分Good good study day day up
为单个单词。
Sub Demo1()
Dim strString As String
Dim varResult As Variant
Dim arrResult() As String
strString = "Good good study day day up"
varResult = VBA.Split(strString)
arrResult = VBA.Split(strString)
End Sub
VBA.Split(strString)
省略delimiter
参数,则使用空格做为分隔符,拆分为6个单词字符串,在【本地窗口】中可以查看数组的值,如下图所示。
请注意变量声明语句,用于保存结果的数组,可以使用如下两种方式:Variant变量或者字符串数组,但是不可用声明为Variant数组。
Dim varResult As Variant
Dim arrResult() As String
一般情况下,都无须指定LIMIT
参数,下面看一个使用LIMIT
参数的例子。对于一些国外地址如:888, Ocean Wind Rd, Markham, V4A
,需要拆分为888
,Ocean Wind Rd
和Markham, V4A
,而不是拆分为4段,此时就需要设置LIMIT
参数为3。
Sub Demo2()
Dim strString As String
Dim arrResult() As String
Dim i As Integer
strString = "888, Ocean Wind Rd, Markham, V4A"
arrResult = VBA.Split(strString, ",", 3)
For i = LBound(arrResult) To UBound(arrResult)
Debug.Print Trim(arrResult(i))
Next i
End Sub
接下来看一下如何使用compare
参数,下面示例代码中设置为vbTextCompare
,即执行文本比较,也就是说忽略字符大小写区别(S和s都可以作为分界符)。如下代码结果为包含4个元素的字符串数组(AAA
,BBB
,CCC
和DDD
)。
Sub Demo3()
Dim strString As String
Dim arrResult() As String
Dim i As Integer
strString = "AAAsBBBSCCCsDDD"
arrResult = VBA.Split(strString, delimiter:="s", compare:=vbTextCompare)
For i = LBound(arrResult) To UBound(arrResult)
Debug.Print Trim(arrResult(i))
Next i
End Sub
如果将compare
参数设置为vbBinaryCompare
,那么结果就会不同了。
Sub Demo4()
Dim strString As String
Dim arrResult() As String
Dim i As Integer
strString = "AAAsBBBSCCCsDDD"
arrResult = VBA.Split(strString, delimiter:="s", compare:=vbBinaryCompare)
For i = LBound(arrResult) To UBound(arrResult)
Debug.Print Trim(arrResult(i))
Next i
End Sub
字符串被拆分为三段,BBB
和CCC
之间的S
不再做为分界符。
AAA
BBBSCCC
DDD
通过这个讲解,希望大家完全明白了SPLIT
函数的用法。