如何使用vbscript创建定时消息?
问题描述:
我想创建一个vbs文件,提醒我每隔1小时休息一次。它应该打开一个新的窗口,以“小休息时间”作为消息。我会一直运行脚本。只需要每隔1小时打开一个小信息框,并在30秒后关闭信息框。我想知道如果我可以使用时间,而不是使用大循环。 感谢您的帮助。如何使用vbscript创建定时消息?
答
只要给为创建计划VBScript文件每隔一小时要执行此批处理文件一试:Create_scheduled_Vbscript.bat
@echo off
color 0A & Mode 80,5
Title Create a scheduled vbscript file to be executed every hour
set "VBSFilePath=c:\Msg.vbs"
set "TaskName=BreakTime"
:CreateVBSFile
(
echo strText = "Time for a small break !"
echo set ws=CreateObject("wscript.shell"^)
echo ws.Popup strText,30,strText,vbInformation
)>"%VBSFilePath%"
Rem 60 minutes = 1Hour
Call :Create_Schedule_Task 60 "%TaskName%" "%VBSFilePath%"
Rem Just to query the BreakTime TaskName
Schtasks /Query /TN "%TaskName%" | find /i "%TaskName%"
pause & exit
::***********************************************************************
:Create_Schedule_Task <Repeat_Task_Every(N)Minute> <TaskName> <FilePath>
Schtasks /create /SC minute /MO %1 /TN "%~2" /TR "%~3"
exit /b
::***********************************************************************
如果你想以任何理由删除TaskName = BreakTime
只是执行这个小的批处理文件:Delete_Taskname.bat
@echo off
set "TaskName=BreakTime"
SCHTASKS /DELETE /TN "%TaskName%" /F
pause
欢迎来到SO。本网站不是代码编写服务,不适用于提供完整的解决方案。预计用户将展示一些努力和代码,而SO在此期间将帮助您解决具体的编程问题。你有没有尝试过任何东西? –
你应该[编辑你的问题](https://*.com/posts/46056141/edit)并发布到目前为止,你作为代码尝试过什么! – Hackoo
只需创建一个Windows Scheduled任务即可每小时运行脚本。批处理文件与vbscript不同。如果你想要一个VBScript,然后从问题中删除批处理文件标签。 – Squashman