Cmake入门实战

本文参考：

https://www.hahack.com/codes/cmake/
https://cmake.org/cmake-tutorial/
https://www.lijiaocn.com/%E6%8A%80%E5%B7%A7/2019/01/22/cmake-usage.html

第一篇博客是腾讯大佬写的，实在太好了，这里特此验证转载吧，特此感谢。

ps: 本文开发环境为Typora，最好的Markdown编辑器！

Cmake基本使用

你或许听过好几种 Make 工具，例如 GNU Make ，QT 的 qmake ，微软的 MS nmake，BSD Make（pmake），Makepp，等等。这些 Make 工具遵循着不同的规范和标准，所执行的 Makefile 格式也千差万别。这样就带来了一个严峻的问题：如果软件想跨平台，必须要保证能够在不同平台编译。而如果使用上面的 Make 工具，就得为每一种标准写一次 Makefile ，这将是一件让人抓狂的工作。

CMake就是针对上面问题所设计的工具：它首先允许开发者编写一种平台无关的 CMakeList.txt 文件来定制整个编译流程，然后再根据目标用户的平台进一步生成所需的本地化 Makefile 和工程文件，如 Unix 的 Makefile 或 Windows 的 Visual Studio 工程。从而做到“Write once, run everywhere”。显然，CMake 是一个比上述几种 make 更高级的编译配置工具。一些使用 CMake 作为项目架构系统的知名开源项目有 VTK、ITK、KDE、OpenCV、OSG 等 [1]。

在 linux 平台下使用 CMake 生成 Makefile 并编译的流程如下：

编写 CMake 配置文件 CMakeLists.txt 。
执行命令 cmake PATH 或者 ccmake PATH 生成 Makefile，其中， PATH 是 CMakeLists.txt 所在的目录
使用 make 命令进行编译。

入门案例：单个源文件

说明：该代码本人亲自敲了一份，学习师兄的变量风格。同时该代码采用最简单的当前目录Demo1进行编译。

对于简单的项目，只需要写几行代码就可以了。例如，假设现在我们的项目中只有一个源文件 main.cc]，该程序的用途是计算一个数的指数幂。

#include <stdio.h>
#include <stdlib.h>


/**
 * power - Caculate the power of number.
 * @param base: Base value.
 * @param exponent: Expnent value.
 *
 * @return base rasised to the power exponent
 */


double power(double base, int exponent)
{
	int result = base;
	int i;

	if(exponent == 0) 
	{
		return 1;
	}

	for(i = 1; i < exponent; ++i)
	{
		result = result * base;
	}

	return result;
}


int main(int argc, char *argv[])
{
	if(argc < 3)
	{
		printf("Usage: %s base exponent \n",argv[0]);
		return -1;
	}

	double base = atof(argv[1]);
	int exponent = atoi(argv[2]);
    double result = power(base,exponent);
	printf("%g ^ %d is %g\n",base,exponent,result);



	return 0;
}

编写 CMakeLists.txt

首先编写 CMakeLists.txt 文件，并保存在与 main.cc源文件同个目录下：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)

# 项目信息
project (Demo1)

# 指定生成目标
add_executable (Demo main.cc)

CMakeLists.txt 的语法比较简单，由命令、注释和空格组成，其中命令是不区分大小写的。符号 # 后面的内容被认为是注释。命令由命令名称、小括号和参数组成，参数之间使用空格进行间隔。

对于上面的 CMakeLists.txt 文件，依次出现了几个命令：

cmake_minimum_required：指定运行此配置文件所需的 CMake 的最低版本；
project：参数值是 Demo1，该命令表示项目的名称是 Demo1 。
add_executable：将名为 main.cc 的源文件编译成一个名称为 Demo 的可执行文件。

编译项目

之后，在当前目录执行 cmake . ，得到 Makefile 后再使用 make 命令编译得到 Demo1 可执行文件。
Cmake入门实战

多个源文件

同一目录，多个源文件

上面的例子只有单个源文件。现在假如把 power 函数单独写进一个名为 MathFunctions.c 的源文件里，使得这个工程变成如下的形式：

./Demo2
    |
    +--- main.cc
    |
    +--- MathFunctions.cc
    |
    +--- MathFunctions.h

这个时候，CMakeLists.txt 可以改成如下的形式：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)
# 项目信息
project (Demo2)
# 指定生成目标
add_executable(Demo main.cc MathFunctions.cc)

唯一的改动只是在 add_executable 命令中增加了一个 MathFunctions.cc 源文件。这样写当然没什么问题，但是如果源文件很多，把所有源文件的名字都加进去将是一件烦人的工作。更省事的方法是使用 aux_source_directory 命令，该命令会查找指定目录下的所有源文件，然后将结果存进指定变量名。其语法如下：

aux_source_directory(<dir> <variable>)

因此，可以修改 CMakeLists.txt 如下：

# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)

# 项目信息
project (Demo2)

# 查找当前目录下所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory (. DIR_SRCS)


# 指定生成目标
add_executable (Demo ${DIR_SRCS})

这样，CMake 会将当前目录所有源文件的文件名赋值给变量 DIR_SRCS ，再指示变量 DIR_SRCS 中的源文件需要编译成一个名称为 Demo 的可执行文件。

多个目录，多个源文件

现在进一步将 MathFunctions.h 和 MathFunctions.cc 文件移动到 math 目录下。

./Demo3
    |
    +--- main.cc
    |
    +--- math/
          |
          +--- MathFunctions.cc
          |
          +--- MathFunctions.h

对于这种情况，需要分别在项目根目录 Demo3 和 math 目录里各编写一个 CMakeLists.txt 文件。为了方便，我们可以先将 math 目录里的文件编译成静态库再由 main 函数调用。

根目录中的 CMakeLists.txt

# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)

# 项目信息
project (Demo3)

# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory(. DIR_SRCS)

# 添加 math 子目录
add_subdirectory(math)

# 指定生成目标 
add_executable(Demo main.cc)

# 添加链接库
target_link_libraries(Demo MathFunctions)

该文件添加了下面的内容: 第3行，使用命令 add_subdirectory 指明本项目包含一个子目录 math，这样 math 目录下的 CMakeLists.txt 文件和源代码也会被处理。第6行，使用命令 target_link_libraries 指明可执行文件 main 需要连接一个名为 MathFunctions 的链接库。

子目录中的 CMakeLists.txt：

# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_LIB_SRCS 变量
aux_source_directory(. DIR_LIB_SRCS)

# 生成链接库
add_library (MathFunctions ${DIR_LIB_SRCS})

在该文件中使用命令 add_library 将 src 目录中的源文件编译为静态链接库。

注意：由于cmake没有类似"cmake clean"清理所有编译生成文件的clean命令，因此我们在源代码目录之外建一个build目录，在这个build目录下进行cmake，如果想清理，删掉build下所有文件即可

mkdir build

cd build

cmake ..

make

Cmake入门实战
此时编译产生的缓存文件以及可执行文件’Demo’均在build目录下。

Cmake进阶使用

为工程添加测试

添加测试同样很简单。CMake 提供了一个称为 CTest 的测试工具。我们要做的只是在项目根目录的 CMakeLists 文件中调用一系列的 add_test 命令。

# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)

set(CMAKE_BUILD_TYPE "Debug")
set(CMAKE_CXX_FLAGS_DEBUG "$ENV{CXXFLAGS} -O0 -Wall -g -ggdb")
set(CMAKE_CXX_FLAGS_RELEASE "$ENV{CXXFLAGS} -O3 -Wall")

# 项目信息
project (Demo3)

# 查找当前目录下所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory (. DIR_SRCS)


# 添加 math 子目录
add_subdirectory (math)

# 指定生成目标
add_executable (Demo ${DIR_SRCS})

# 添加链接库
target_link_libraries(Demo MathFunctions)


# 启动测试
enable_testing()

# 测试帮助信息是否可以正常显示
add_test (test_usage Demo)
set_tests_properties(test_usage 
	PROPERTIES PASS_REGULAR_EXPRESSION "Usage: .* base exponent")
# 测试程序是否成功运行(不检查返回结果)
add_test (test_run Demo 5 2)

# 测试程序是否成功运行(检查返回结果)
add_test (test_5_2 Demo 5 2)
set_tests_properties(test_5_2 
	PROPERTIES PASS_REGULAR_EXPRESSION "is 25")

# 测试程序是否成功运行(检查返回结果)
add_test (test_10_5 Demo 10 5)
set_tests_properties(test_10_5
	PROPERTIES PASS_REGULAR_EXPRESSION "is 100000")

上面的代码包含了四个测试。第一个测试test_usage 帮助信息是否可以正常显示；第二个测试test_run用来测试程序是否成功运行并返回 0 值。第三个、第四个测试分别用来测试 5 的平方、10 的 5 次方是否都能得到正确的结果。其中 PASS_REGULAR_EXPRESSION用来测试输出是否包含后面跟着的字符串（若包含则表明输出正确）。

让我们看看测试的结果：
Cmake入门实战

如果要测试更多的输入数据，像上面那样一个个写测试用例未免太繁琐。这时可以通过编写宏来实现：

# 定义一个宏，用来简化测试工作
macro (do_test arg1 arg2 result)
  add_test (test_${arg1}_${arg2} Demo ${arg1} ${arg2})
  set_tests_properties (test_${arg1}_${arg2}
    PROPERTIES PASS_REGULAR_EXPRESSION ${result})
endmacro (do_test)
 
# 使用该宏进行一系列的数据测试
do_test (5 2 "is 25")
do_test (10 5 "is 100000")

支持 gdb

让 CMake 支持 gdb 的设置也很容易，只需要指定 Debug 模式下开启 -g 选项：

set(CMAKE_BUILD_TYPE "Debug")
set(CMAKE_CXX_FLAGS_DEBUG "$ENV{CXXFLAGS} -O0 -Wall -g -ggdb")
set(CMAKE_CXX_FLAGS_RELEASE "$ENV{CXXFLAGS} -O3 -Wall")

注意：这里如果使用调试模式，需要将所有的CMakeList.txt中添加这三行，否则无法读取符号表。

其他功能

时间有限，这些功能就不测试了，如有需要请参考原作者文章

自定义编译选项
安装和测试
添加环境检查
添加版本号
生成安装包
将其他平台的项目迁移到 CMake