Android 引入AspectJ

• l AspectJ比较强大，除了支持对source文件（即aj文件、或@AspectJ注解的Java文件，或普通java文件）直接进行编译外，
• l 还能对Java字节码（即对class文件）进行处理。有感兴趣的同学可以对aspectj-test小例子的class文件进行反编译，你会发现AspectJ无非是在被选中的JPoint的地方加一些hook函数。当然Before就是在调用JPoint之前加，After就是在JPoint返回之前加。
• l 更高级的做法是当class文件被加载到虚拟机后，由虚拟机根据AOP的规则进行hook。

•                 自定义Gradle Plugin
  
•                 在apply 方法中实现参数设置
  

import com.android.build.gradle.LibraryPlugin
import org.aspectj.bridge.IMessage
import org.aspectj.bridge.MessageHandler
import org.aspectj.tools.ajc.Main
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.tasks.compile.JavaCompile

public class AopPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {
        //判断应用此Module的Target类型是AppPlugin还是LibraryPlugin
        def hasApp = project.plugins.withType(AppPlugin)
        def hasLibrary = project.plugins.withType(LibraryPlugin)
        if (!hasApp && !hasLibrary) {
            throw new IllegalStateException("'android' or 'android-library' plugin required.")
        }

        final def log = project.logger
        final def variants
        if (hasApp) {
            variants = project.android.applicationVariants
        } else {
            variants = project.android.libraryVariants
        }

        //添加依赖
        project.dependencies {
            compile 'org.aspectj:aspectjrt:1.8.9'
        }

        variants.all { variant ->
            JavaCompile javaCompile = variant.javaCompile
            javaCompile.doLast {
                String[] args = [
                    "-showWeaveInfo",
                    "-1.5",
                    "-inpath", javaCompile.destinationDir.toString(),
                    "-aspectpath", javaCompile.classpath.asPath,
                    "-d", javaCompile.destinationDir.toString(),
                    "-classpath", javaCompile.classpath.asPath,
                    "-bootclasspath", project.android.bootClasspath.join(File.pathSeparator)
                ]

                log.debug "ajc args:" + Arrays.toString(args)
                printf("Aspectj compiler args :" + Arrays.toString(args))
                MessageHandler handler = new MessageHandler(true);
                new Main().run(args, handler);
                for (IMessage message : handler.getMessages(null, true)) {
                    switch (message.getKind()) {
                        case IMessage.ABORT:
                        case IMessage.ERROR:
                        case IMessage.FAIL:
                            log.error message.message, message.thrown
                            break;

                        case IMessage.WARNING:
                            log.warn message.message, message.thrown
                            break;

                        case IMessage.INFO:
                            log.info message.message, message.thrown
                            break;

                        case IMessage.DEBUG:
                            log.info message.message, message.thrown
                            break;
                    }
                }
            }
        }
    }
}