如何获取已删除记录的数量？

Question

我尝试这样做：

function TMyClass.removeRecords(...) : integer; 
var 
    aC : TADOCommand; 
    aRS : _RecordSet; 
begin 
    aC := createADOCommand; 
    try 
    aC.Connection := fConnection; 
    aC.commandText := getDeleteModelSQLCommand(...); 
    aRS := aC.Execute; 
    {$ifdef debug_AlwaysOne} 
     result := 1; 
    {$else} 
     result := aRS.RecordCount; 
    {$endif} 
    finally 
    releaseADOCommand(aC); 
    end; 
end; 

它正确地定义debug_AlwaysOne条件运行。

然而，在那读RecordCount行，它提出了一个错误：

Operation is not allowed when the object is closed

有没有什么办法让删除记录的数目？我知道我可以在删除之前执行一个聚合查询。但是我可以在没有其他SQL命令调用的情况下执

Answer 1

使用重载版本的TADOCommand.Execute()具有RecordsEffected输出参数：

function Execute(var RecordsAffected: Integer; const Parameters: OleVariant): _Recordset; overload; 

例如：

function TMyClass.removeRecords(...) : integer; 
var 
    aC : TADOCommand; 
begin 
    aC := createADOCommand; 
    try 
    aC.Connection := fConnection; 
    aC.commandText := getDeleteModelSQLCommand(...); 
    {$ifdef debug_AlwaysOne} 
    aC.Execute; 
    Result := 1; 
    {$else} 
    aC.Execute(Result, EmptyParam); 
    {$endif} 
    finally 
    releaseADOCommand(aC); 
    end; 
end;