Shader效果源码（一）——Sin波动 + UV滚动+选择UV

一些项目源码，我会放在GitHub里边

https://github.com/Timor666/ProjectCode

SIN波动

Shader "Timor/01/sin波动"
{
	//属性块
	Properties
	{
		_Arange("高度",float) =1
		_Frenquacy("频率",float) =1
		_Speed("速度",float) =1
	}

	/*
	原理：通过改变顶点的坐标y，使用sin函数，和_Time.y
	*/
	SubShader
	{
		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			float _Speed;
			float _Arange;
			float _Frenquacy;

			 

			struct appdata
			{
				float4 vertex : POSITION;	//使用模型空间顶点位置填充
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;	//裁剪坐标下位置
			};

			//顶点函数
			v2f vert (appdata v)
			{
				v2f o;
				float timer = _Time.y * _Speed;
				float waver = _Arange * sin(timer + v.vertex.x * _Frenquacy);
			
				v.vertex.y = v.vertex.y + waver;

				o.vertex = UnityObjectToClipPos(v.vertex);
				return o;
			}
			
			
			//片元函数
			fixed4 frag (v2f i) : SV_Target	//SV_Target输出值储存到渲染目标
			{
				return fixed4(0,1,0.5,0.5);	//返回绿色
			}
			ENDCG
		}
	}
}

uv滚动

Shader "Timor/01/UV滚动"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_Speed ("速度",Range(-10,20)) =1
	}
	SubShader
	{
		// No culling or depth
	//	Cull Off ZWrite Off ZTest Always

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			float _Speed;

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			
			sampler2D _MainTex;

			fixed4 frag (v2f i) : SV_Target
			{
				float2 uv = i.uv;
				uv.x += _Time.x * _Speed;
				//uv.y += _Time.y;

				fixed4 col = tex2D(_MainTex, uv);
				// just invert the colors
				//col.rgb = 1 - col.rgb;
				return col;
			}
			ENDCG
		}
	}
}

UV旋转

Shader "Timor/02/旋转UILoading"
{
	Properties
	{
		_MainTex ("图片",2D) = "white" {}
		_Speed("旋转速度",Range(-50,300)) = 30
	}
	SubShader
	{
		 
		Blend SrcAlpha OneMinusSrcAlpha //开启alpha 混合
		Pass
		{
			CGPROGRAM
			float _Speed;
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			
			sampler2D _MainTex;

			fixed4 frag (v2f i) : SV_Target
			{
				//移动到原点
				float2 tempUV = i.uv;
				tempUV -= float2(0.5,0.5);	

				//舍弃对角线
				if(length(tempUV)>0.5){	
					return fixed4(0,0,0,0);
				}

				float2 finalUV =0;
				float angle = _Time.x * _Speed;
				
				//旋转
				finalUV.x = tempUV.x * cos(angle) - tempUV.y *sin(angle);	
				finalUV.y = tempUV.x * sin(angle) + tempUV.y * cos(angle);
				
				//移动回去
				finalUV += float2(0.5,0.5);
				fixed4 col = tex2D(_MainTex, finalUV);
			 
				return col;
			}
			ENDCG
		}
	}
}