使用xslt将xml结构转换为另一个xml结构
我有一个问题。我有以下源XML文件:使用xslt将xml结构转换为另一个xml结构
源XML:
<Container>
<DataHeader>
<c id="b" value="TAG" />
<c id="g" value="Info" />
</DataHeader>
<Data>
<Rows>
<r no="1">
<c id="b" value="uid1" uid="T.A.uid1" />
<c id="g" value="uid1|tag1|attr1|somevalue1" />
</r>
<r no="1">
<c id="b" value="uid1" uid="T.A.uid1" />
<c id="g" value="uid1|tag1|attr2|somevalue2" />
</r>
<r no="2">
<c id="b" value="uid1" uid="T.A.uid1" />
<c id="g" value="uid1|tag2|attr3|somevalue3" />
</r>
<r no="10">
<c id="b" value="uid2" uid="T.A.uid2" />
<c id="g" value="uid2|tag1|attr1|somevalue4" />
</r>
<r no="11">
<c id="b" value="uid2" uid="T.A.uid2" />
<c id="g" value="uid2|tag2|attr3|somevalue5" />
</r>
</Rows>
</Data>
</Container>
元素 'ç' id为 '克' 是在源XML重要。这是一个连接的字符串,其值由'|'。我们需要这个值来制作目标xml。 元素'c'与id'b''您可以用来分隔'uid'。值的
示例和explantion:
<c id="g" value="uid1|tag1|attr1|somevalue1" />
**uid value** | element node | **attribute** | attribute value
**uid1** | tag1 | **attr1** |somevalue1
的Al元素与相同的 'UID' 具有要被汇集到1张 “TestTag” 元件(见目标XML)。 需要将相同父元素(例如'tag1')的属性(attr1,attr2)添加到1个元素。 我只能使用xslt(xpath)1.0。
转换后目标xml文件应该看起来像这样。通过XSL转换后
目标XML:
<Container>
<TestTag>
<object UID="T.A.uid1" Name="uid1"/>
<tag1 attr1="somevalue1" attr2="somevalue2"/>
<tag2 attr3="*somevalue3"/>
</TestTag>
<TestTag>
<Iobject UID="T.A.uid2" Name="uid2"/>
<tag1 attr1="somevalue4" />
<tag2 attr3="somevalue5"/>
</TestTag>
</Container>
什么是转换XML源到目标XML可能的解决方案?我尝试了几件事,但我现在被卡住了。
这不正是困难,但令人难以置信的是由于大量的(但必要的)嵌套使用substring-before()
和substring-after()
。
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
<!-- index <c> nodes by their @id + "uid value" -->
<xsl:key name="kObject" match="r/c" use="
concat(@id, '|', @value)
" />
<!-- index <c> nodes by their @id + "uid value" -->
<xsl:key name="kTagByUid" match="r/c" use="
concat(@id, '|', substring-before(@value, '|'))
" />
<!-- index <c> nodes by their @id + "uid value" + "tag name" -->
<xsl:key name="kTagByName" match="r/c" use="
concat(@id, '|',
substring-before(
@value,
substring-after(substring-after(@value, '|'), '|')
)
)
" />
<xsl:variable name="vTagId" select="/Container/DataHeader/c[@value='TAG'][1]/@id" />
<xsl:variable name="vInfoId" select="/Container/DataHeader/c[@value='Info'][1]/@id" />
<!-- processing starts here -->
<xsl:template match="Container">
<xsl:copy>
<!-- apply templates to unique <c @id=$vTagId> tags -->
<xsl:apply-templates mode="tag" select="
Data/Rows/r/c[@id=$vTagId][
generate-id()
=
generate-id(key('kObject', concat(@id, '|', @value))[1])
]
" />
</xsl:copy>
</xsl:template>
<xsl:template match="c" mode="tag">
<TestTag>
<object UID="{@uid}" name="{@value}" />
<!-- apply templates to unique <c @id="g"> tags -->
<xsl:apply-templates mode="info" select="
key('kTagByUid', concat($vInfoId, '|', @value))[
generate-id()
=
generate-id(
key(
'kTagByName',
concat(@id, '|',
substring-before(
@value,
substring-after(substring-after(@value, '|'), '|')
)
)
)[1]
)
]
" />
</TestTag>
</xsl:template>
<xsl:template match="c" mode="info">
<!-- select 'uid1|tag1|' - it's the key to kTagByName -->
<xsl:variable name="key" select="substring-before(@value, substring-after(substring-after(@value, '|'), '|'))" />
<!-- select 'tag1' - it's the element name -->
<xsl:variable name="name" select="substring-before(substring-after($key, '|'), '|')" />
<xsl:element name="{$name}">
<xsl:for-each select="key('kTagByName', concat(@id, '|', $key))">
<!-- select 'attr1|somevalue1' - it's the attribute definition -->
<xsl:variable name="attrDef" select="substring-after(@value, $key)" />
<!-- create an attribute -->
<xsl:attribute name="{substring-before($attrDef, '|')}">
<xsl:value-of select="substring-after($attrDef, '|')" />
</xsl:attribute>
</xsl:for-each>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
产生:
<Container>
<TestTag>
<object UID="T.A.uid1" name="uid1" />
<tag1 attr1="somevalue1" attr2="somevalue2"></tag1>
<tag2 attr3="somevalue3"></tag2>
</TestTag>
<TestTag>
<object UID="T.A.uid2" name="uid2" />
<tag1 attr1="somevalue4"></tag1>
<tag2 attr3="somevalue5"></tag2>
</TestTag>
</Container>
注意,这并不注意重复属性定义。如果您碰巧有uid1|tag1|attr1|somevalue1
及更高版本uid1|tag1|attr1|othervalue1
,那么您将最终得到一个属性:attr1="othervalue1"
,因为<xsl:for-each>
都会轮到他们,而后者会赢(即在输出中结束)。
也可以迎合这一点,它将需要一个更多的关键和一个Muenchian分组,我将把它作为读者的练习。嘿。 ;)
+1,很好的答案[15个字符] – 2010-02-18 04:07:14
Hello Tomalak, 感谢您的帮助。您的解决方案效果非常好。 但现在我有另一个问题。 在源xml中还有一个DataHeader元素。我们不希望匹配id的值,因为这是生成的,组合ID和值可能每次都是不同的。 我们的解决方案是使用xsl:key
问题是,在您的示例中,您在xsl:key中的id匹配模板匹配,我不能在xsl:key或模板匹配中使用变量。
+1很好的第一次问题。欢迎来到堆栈溢出! – Tomalak 2010-02-17 17:11:37