如何搜索数组中的空值/空值，然后使用其他值擦除和更新字段

Question

我正在使用delphi打印标签。我将值存储在数组中并打印相同。我想知道，当我对标签没有价值并使下一个标签利用为空值或空值提供的空间时，我们如何删除空间。

Answer 1

所以，如果我理解你的权利，你有一个Array与字符串值这样['Item1', 'Item2', '', 'Item4']，你想使它成为['Item1', 'Item2', 'Item4']删除空项目？

正如评论所述，这可以用一个好的旧如果声明，但我宁愿给你一个通用的解决方案。

首先要创建一个带有助手的新单元，该助手可以从阵列中删除任何给定的值。

unit ArrayHelperU; 

interface 

type 
    ArrayHelper = record 
    class procedure RemoveAll<T>(var Values: TArray<T>; const Value: T); static; 
    end; 

implementation 

uses 
    Generics.Defaults; 

{ TArrayHelper } 

class procedure ArrayHelper.RemoveAll<T>(var Values: TArray<T>; const Value: T); 
var 
    I, Count: Integer; 
    EqualityComparer: IEqualityComparer<T>; 
begin 
    EqualityComparer := TEqualityComparer<T>.Default; 

    Count := 0; 

    for I := low(Values) to high(Values) do 
    if not EqualityComparer.Equals(Values[I], Value) then 
    begin 
     Values[Count] := Values[I]; 
     inc(Count); 
    end; 

    SetLength(Values, Count); 
end; 

end. 

下一步是调用它。在我小的演示项目我已经把TMemo空白表单，然后我从FormCreate

uses 
    ArrayHelperU; 

procedure TForm36.FormCreate(Sender: TObject); 
var 
    Values: TArray<string>; 
    Buffer, Element: String; 
    i: Integer; 
begin 
    //Make room for 10 elements 
    Setlength(Values, 10); 

    //Initialize the aray with some dummy values 
    //Some of them are blanks 
    for i := Low(Values) to High(Values) do 
    if i mod 2 = 0 then 
     Values[i] := 'Item' + IntToStr(i); 


    //Print the array to the screen 
    Memo1.Lines.Text := 'BEFORE: '; 
    Buffer := '['; 
    for Element in Values do 
    Buffer := Buffer + #39 + Element + #39 + ' ,'; 
    Buffer[Length(Buffer)] := ']'; 
    Memo1.Lines.Add(Buffer); 

    //Call our ArrayHelper from befor 
    ArrayHelper.RemoveAll<string>(Values, ''); 

    //Print the array to the screen 
    Buffer := '['; 
    for Element in Values do 
    Buffer := Buffer + #39 + Element + #39 + ' ,'; 
    Memo1.Lines.Add(''); 
    Memo1.Lines.Add('AFTER:'); 
    Buffer[Length(Buffer)] := ']'; 
    Memo1.Lines.Add(Buffer); 
end; 

叫帮手，我放在评论中的代码，所以你可以看到它是如何工作的。

剩下的只是显示结果。

Answer 2

在Delphi 7使用旧的好的动态数组。

使用字符串的值类型，就可以解决这个问题如下：

创建一个新的VCL应用程序，放置一个备忘录，然后：

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls; 

type 
    TForm1 = class(TForm) 
    Memo1: TMemo; 
    procedure FormCreate(Sender: TObject); 
    private 
    { Private declarations } 
    procedure DynamicStringArrayWay; 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.DynamicStringArrayWay; 
var 
    ValueArray : array of string; 
    n : Integer; 
    n2 : Integer; 
begin 
    SetLength(ValueArray, 6); 

    // fill array: 
    ValueArray[0] := 'LabelA'; 
    ValueArray[1] := ''; 
    ValueArray[2] := 'LabelB'; 
    ValueArray[3] := ''; 
    ValueArray[4] := 'LabelC'; 
    ValueArray[5] := 'LabelD'; 

    // reduce: 
    for n := Length(ValueArray)-1 downto 0 do 
    begin 
    if (ValueArray[n]='') then 
    begin 
     // delete element n: 
     for n2 := n to Length(ValueArray)-2 do 
     ValueArray[n2] := ValueArray[n2+1]; 
     SetLength(ValueArray, Length(ValueArray)-1); 
    end; 
    end; 

    // print: 
    for n := 0 to Length(ValueArray)-1 do 
    Memo1.Lines.Add(ValueArray[n]); 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    DynamicStringArrayWay; 
end; 


end.