Grails域类的属性拦截

Question

我想拦截对域类属性的调用来实现访问控制。

我的第一次尝试是重写setProperty和getProperty。通过这样做，我禁用Grails领域类的所有好的功能，如

domainClass.properties = params 

和数据类型的自动转换。

接下来的尝试是使用DelegatingMetaClass，它使我至少能够打印出实际调用周围的一些漂亮的日志消息。但我无法弄清楚如何访问实际的对象来评估权限。

最后，groovy.lang.Interceptor似乎是一个不错的选择，因为我可以访问实际的对象。但这是正确的方式吗？我如何能够强制拦截所有域类？

非常感谢。

的问候，丹尼尔

Answer 1

只要你引用真正的版本，您可以覆盖的getProperty和setProperty。加入这样的代码来引导对添加拦截所有域类：

class BootStrap { 

    def grailsApplication 

    def init = { servletContext -> 

     for (dc in grailsApplication.domainClasses) { 
     dc.class.metaClass.getProperty = { String name -> 
      // do stuff before access 
      def result 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       result = metaProperty.getProperty(delegate) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after access 
      result 
     } 

     dc.class.metaClass.setProperty = { String name, value -> 
      // do stuff before update 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       metaProperty.setProperty(delegate, value) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after update 
     } 
     } 
    } 

    def destroy = {} 
}