在ColdFusion中创建具有PUT请求的Wufoo webhook

Question

我正在为Wufoo构建正确的PUT request而遇到麻烦。

在我所有的努力我看到了同样的错误：

404 A WebHook must contain a url parameter.

这里是版本JSON数据类型：

<cfset local.action = "forms/#local.formHash#/webhooks.json" /> 

<cfset local.request = {"url" : local.webHookURL, "handshakeKey" : local.webHookKey} /> 

<cfset local.request["handshakeKey"] = local.webHookKey /> 

<cfhttp url="#local.baseURL##local.action#" method="put" username="#local.apiKey#" password="#local.apiPass#"> 
    <cfhttpparam type="header" name="Content-Type" value="application/json; charset=UTF-8" /> 
    <cfhttpparam type="body" value="#SerializeJSON(local.request)#" /> 
</cfhttp> 

同样的错误使用file时：

<cfset local.action = "forms/#local.formHash#/webhooks.json" /> 

<cfset local.request = {"url" : local.webHookURL, "handshakeKey" : local.webHookKey} /> 

<cffile action="write" file="#GetTempDirectory()#webhook.json" output="#SerializeJSON(local.request)#"> 

<cfhttp url="#local.baseURL##local.action#" method="put" username="#local.apiKey#" password="#local.apiPass#"> 
    <cfhttpparam type="header" name="Content-Type" value="application/json; charset=UTF-8" /> 
    <cfhttpparam type="file" mimetype="application/json" name="json" file="#GetTempDirectory()#webhook.json" /> 
</cfhttp> 

---

UPDATE：

为了使代码在ACF的工作（我的代码在只有Railo）使用这个语法要求：

<cfset local.request = {} /> 
<cfset local.request["url"] = local.webHookURL /> 
<cfset local.request["handshakeKey"] = local.webHookKey /> 

两种方法应该产生区分大小写键相同JSON。

---

而且我已经试过了XML数据类型：

<cfset local.action = "forms/#local.formHash#/webhooks.xml" /> 

<cfsavecontent variable="putXML"> 
<cfoutput> 
<?xml version="1.0" encoding="UTF-8"?> 
<WebHookPutRequest> 
<url>#XMLFormat(local.webHookURL)#</url> 
<handshakeKey>#XMLFormat(local.webHookKey)#</handshakeKey> 
</WebHookPutRequest> 
</cfoutput> 
</cfsavecontent> 

<cffile action="write" file="#GetTempDirectory()#webhook.xml" output="#Trim(putXML)#"> 

<cfhttp url="#local.baseURL##local.action#" method="put" username="#local.apiKey#" password="#local.apiPass#"> 
    <cfhttpparam type="header" name="Content-Type" value="application/xml; charset=UTF-8" /> 
    <cfhttpparam type="body" value="#putXML#" /> 
</cfhttp> 

在这里我不知道如果我的XML是正确的，但对于JSON一切都应该罚款。

任何想法我的代码有什么问题？

在此先感谢。

Answer 1

Wufoo asks for要将参数作为后置参数传递给Web Hook API。尝试使用application/x-www-form-urlencoded编码作为请求的主体。在ColdFusion中，您可以使用<cfhttpparam type="FormField" />执行此操作。

<cfhttpparam type="FormField" name="url" value="#local.webHookURL#" /> 
<cfhttpparam type="FormField" name="handshakeKey" value="#local.webHookKey#" /> 

但是，ColdFusion用PUT方法拒绝了这种技术。您可以使用自己的身体编码：

<cfhttpparam type="header" name="Content-Type" value="application/x-www-form-urlencoded; charset=UTF-8" /> 
<cfhttpparam type="body" value="url=#UrlEncode(local.webHookURL)#&handshakeKey=#UrlEncode(local.webHookKey)#" /> 

Answer 2

在ColdFusion中，通常，变量名称不区分大小写，也不区分大小写。

<cfset local.request = { 
    url = local.webHookURL, 
    handshakeKey = local.webHookKey 
} /> 

这给你的钥匙URL和HANDSHAKEKEY一个结构。

在Web上，可能包含Wufoo REST API，密钥区分大小写。在这种情况下，Wufoo accepts键url,handshakeKey和metadata-在那个外壳。

在ColdFusion中，使用struct puts（assignments）的关联数组表示法可让您保持所需的精确外壳。

<cfset local.request = { } /> 
<cfset local.request["url"] = local.webHookURL /> 
<cfset local.request["handshakeKey"] = local.webHookKey /> 

这给你的钥匙url和handshakeKey一个结构。

Answer 3

不熟悉这个API，但应该的URL，handshakekey等形式后params？

The following parameters must be passed as post parameters to the Web Hook API

url - this required parameter represents the URL on your server that the Web Hook will call when a new entry is submitted. We do validate the URL and reject malformed URLs.

handshakeKey - this optional parameter is described in the Web Hook integration getting started documentation.

metadata=true - this optional value parameter the Web Hook to send along form/field

我读的方式，它看起来像他们所要求 每个PARAMS的。

错误是暗示它找不到URL参数，也许就是这样。